/**
 * Dragon's Lair was an arcade game released in 1983.
 * It was the first arcade game to feature a laserdisc video player inside the machine.
 * The player pressed the right direction or pressed an all-purpose attack button to avoid danger.
 * If the player failed to press the right command, or otherwise failed, the video would skip to
 * another part of the disc where the hero would die in an appropriate fashion.
 * The average lifetime of a Dragon's Lair cabinet was very low because of its mechanical components
 * and so today many people have never played the game. As a side effect, the entire "interactive video"
 * genre of games fell in to obscurity.
 *
 * This package attempts to recreate a standard Laserdisc game engine.
 * You are invited to make your own "video"game by splicing some video together linearly
 * and marking the scenes' expected player actions, and loop/redirect points in XML.
 * Cuepoints can be defined in an XML file with a start time (beg), end time (end),
 * the place in the video where a user wins something (win) and a place where the user dies (fail)
 * you can also use the (seekpoint) xml tag to force things like looping,
 * a return from a "win" tangent, or, most commonly like in Dragon's Lair,
 * move the player from a death to completely new room - its signature form of consequence.
 *
 * Special attention has been taken to make sure this is Playstation 3 Web Browser compatible.
 * Use X as the attack (mouse click), and the D-Pad as your direction buttons.
 *
 * I hereby release the rights to this code for all to use, share, and collaborate on in happiness
 * Any new versions will be posted somewhere on my website RGBk.org
 *
 * Yours truely,
 * Wray Bowling
 */


package{
	//xml related
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import XML;
	
	//event related
	import flash.events.*;
	
	//video related
	import flash.display.Sprite;
	import fl.video.FLVPlayback;
	import fl.video.MetadataEvent;

	public class Laserdisc extends Sprite{
		private var xml:XML;
		
		//the player has lives and and a score
		var player_lives:int = 3; //decreased by one every time the user fails
		var player_score:int = 0; //increased based on difficulty of what's expected
		//The "Quick Time Event" (as it is called in Shenmue) requires quick action from the player
		var QTE_expected:String = "OK"; //the user action expected, can be Up, Down, Left, Right, Attack, or None
		var QTE_fail:Number = 0.0; //the movie position for the user failing
		var QTE_win:Number = 0.0; //the movie position for the user fulfilling the expected action
		var QTE_gameover:Number = 0.0;
		var QTE_win_enabled = false;
		var QTE_kill_enabled = false;
		
		function Laserdisc():void{
			//vcr is a FLVPlayback component, e.g. a movie player, that is on the stage
			vcr.source = "laserdisc.f4v";
			vcr.pause();
			vcr.playWhenEnoughDownloaded();
			
			//Once the XML file is loaded completely, an event will move on to parsing it
			var XML_LOADER:URLLoader = new URLLoader();
			XML_LOADER.addEventListener(Event.COMPLETE, loadXML);
			XML_LOADER.load(new URLRequest("cuepoints.xml"));
			
			//these events will read in user inputs
			stage.addEventListener(MouseEvent.CLICK, mouseAction);
			stage.addEventListener(KeyboardEvent.KEY_DOWN, keyAction);
			
			//this little beauty sends an event every time a cue point is reached within the video
			vcr.addEventListener(MetadataEvent.CUE_POINT, cueRead);
		}
		
		//function that loads all of the cue points from the XML
		private function loadXML(e:Event):void {
			var xml = new XML(e.target.data);
			
			//adds cue point events for "failpoints" which can only kill the player at failure
			for(var i:int = 0; i< xml.failpoint.length(); i++){
				var cue:Object = new Object();
				var parameters:Object = new Object();

				cue.name = "failpoint";
				cue.time = Number(xml.failpoint[i].start);
				cue.type = "actionscript";
					parameters.key = xml.failpoint[i].key;
					parameters.fail = Number(xml.failpoint[i].fail);
				cue.parameters = parameters;
				vcr.addASCuePoint(cue);
				trace("cue v");
				//ending cuepoint
				var endCue:Object = new Object();
				endCue.name = "close";
				endCue.time = xml.failpoint[i].close;
				vcr.addASCuePoint(endCue);
				trace("cue ^");
			}
			
			//adds cue point events for "winpoints" which can only reward the player. good for menus
			for(var i:int = 0; i< xml.winpoint.length(); i++){
				var cue:Object = new Object();
				var parameters:Object = new Object();

				cue.name = "winpoint";
				cue.time = Number(xml.winpoint[i].start);
				cue.type = "actionscript";
					parameters.key = xml.winpoint[i].key;
					parameters.win = Number(xml.winpoint[i].win);
				cue.parameters = parameters;
				vcr.addASCuePoint(cue);
				trace("cue v");
				//ending cuepoint
				var endCue:Object = new Object();
				endCue.name = "close";
				endCue.time = xml.winpoint[i].close;
				vcr.addASCuePoint(endCue);
				trace("cue ^");
			}
			
			//adds cue point events for "settings" that resets lives
			for(var i:int = 0; i<xml.settings.length(); i++){
				var cue:Object = new Object();
				var parameters:Object = new Object();
				cue.name = "settings";
				cue.time = xml.settings[i].time;
					parameters.lives = int(xml.settings[i].lives);
					parameters.score = int(xml.settings[i].score);
					parameters.gameover = Number(xml.settings[i].gameover);
				cue.parameters = parameters;
				vcr.addASCuePoint(cue);
				trace("~settings~");
			}
			
			//adds cue point events for "seekpoints" that enable looping, and rerouting
			for(var i:int = 0; i<xml.seekpoint.length(); i++){
				var cue:Object = new Object();
				var parameters:Object = new Object();
				cue.name = "seek";
				cue.time = xml.seekpoint[i].time;
					parameters.goto = Number(xml.seekpoint[i].goto);
				cue.parameters = parameters;
				vcr.addASCuePoint(cue);
				trace("<seek>");
			}
			
			//adds cue point events for "scorepoints" that add to the player's score.
			for(var i:int = 0; i<xml.scorepoint.length(); i++){
				var cue:Object = new Object();
				var parameters:Object = new Object();
				cue.name = "score";
				cue.time = xml.scorepoint[i].time;
					parameters.points = Number(xml.scorepoint[i].points);
				cue.parameters = parameters;
				vcr.addASCuePoint(cue);
				trace("/score/");
			}
			
			//adds cue point events for "lifepoints" that typically take away lives.
			for(var i:int = 0; i<xml.lifepoint.length(); i++){
				var cue:Object = new Object();
				var parameters:Object = new Object();
				cue.name = "life";
				cue.time = xml.lifepoint[i].time;
					parameters.lives = Number(xml.lifepoint[i].lives);
				cue.parameters = parameters;
				vcr.addASCuePoint(cue);
				trace("-life-");
			}
		}
		
		//runs for every arrow key press, or spacebar press / mouse click (which share the same one button)
		private function mouseAction(e:MouseEvent):void{
			trace("ATTACK");
			if(QTE_expected == "ATTACK")
				success();
			else
				failure();
			trace("qte: "+QTE_expected);
		}
		
		//interprets a user's keyboard actions.
		//If it's what's expected, turn off the QTE cuepoint, otherwise, you fail
		private function keyAction(e:KeyboardEvent):void{
			switch(e.keyCode){
				case 38:
					trace("UP");
					if(QTE_expected == "UP")
						success();
					else
						failure();
					break;
				case 40:
					trace("DOWN");
					if(QTE_expected == "DOWN")
						success();
					else
						failure();
					break;
				case 37:
					trace("LEFT");
					if(QTE_expected == "LEFT")
						success();
					else
						failure();
					break;
				case 39:
					trace("RIGHT");
					if(QTE_expected == "RIGHT")
						success();
					else
						failure();
					break;
				case 32:
					trace("ATTACK");
					if(QTE_expected == "ATTACK")
						success();
					else
						failure();
					break;
			}
			trace("qte: "+QTE_expected);
		}
		
		//interprets an individual cuepoint
		private function cueRead(e:MetadataEvent):void {
			
			if(e.info.name == "settings"){
				player_lives = e.info.parameters.lives;
				player_score = e.info.parameters.score;
				QTE_gameover = e.info.parameters.gameover;
				scoreBox.text = "score: " + player_score;
				lifeBox.text = "lives: " + player_lives;
				trace("lives="+ player_lives +" score="+ player_score +" gameover="+QTE_gameover);
			}

			if(e.info.name == "seek"){
				vcr.seek(e.info.parameters.goto);
			}
			
			if(e.info.name == "failpoint"){
				trace("killpoint");
				QTE_expected = e.info.parameters.key;
				QTE_kill_enabled = true;
				QTE_win_enabled = false;
				QTE_fail = e.info.parameters.fail;
			}
			
			if(e.info.name == "winpoint"){
				trace("winpoint");
				QTE_expected = e.info.parameters.key;
				QTE_win_enabled = true;
				QTE_win = e.info.parameters.win;
			}
			
			if(e.info.name == "close"){
				trace("ending");
				failure();
			}
			
			if(e.info.name == "score"){
				player_score += e.info.parameters.points;
				scoreBox.text = "score: " + player_score;
				trace("score added");
			}
			
			if(e.info.name == "life"){
				player_lives += e.info.parameters.lives;
				lifeBox.text = "lives: " + player_lives;
				if(player_lives <= 0){
					vcr.seek(QTE_gameover);
				}
			}
		}// end cueRead
		
		private function failure():void{
			if(QTE_expected != "OK" && QTE_kill_enabled){
				vcr.seek(QTE_fail);
				QTE_expected = "OK" //reset action expected
				QTE_kill_enabled = false;
			}
		}
		
		
		private function success():void{
			QTE_expected = "OK";
			if(QTE_win_enabled == true){
				vcr.seek(QTE_win);
				QTE_win_enabled = false;
			}
			trace("win" +QTE_win+ "seeked");
		}
		
	}//end Laserdisc
}//end package